Kool-Andy-Tribute; my submission

Was fun to discover «Pixelmator Pro» functions; there is so many capability!

Kool-Andy-Tribute_4_contest.zip (1.9 MB)

Can’t wait to see reaction.

Little update. v[1]
Select only “.pxd” on start and default location is where the script is.
Show where the final file is saved.

--	Created by: Daniel Rodrigue
--	Created on: 20/09/26 - version [1]
--	Copyright © 2020 Simple & Logik, All Rights Reserved

set vNom to {"TL", "TC", "TR", "ML", "MC", "MR", "BL", "BC", "BR"}
set vFond to {TL:{255, 255, 2}, TC:{0, 173, 239}, TR:{50, 50, 50}, ML:{248, 133, 30}, MC:{236, 28, 36}, MR:{142, 198, 63}, BL:{0, 89, 83}, BC:{255, 255, 2}, BR:{237, 2, 140}}
set vFond to vFond as list

-- Where to save intermediate JPEG component
set vFldrTEMP to path to temporary items

tell application "Finder" to set current_path to container of (path to me) as alias

set vFichier to choose file with prompt "Choose Pixelmator Pro File" of type {"com.pixelmatorteam.pixelmator.document.package"} default location current_path without invisibles
if (vFichier is "") then return

tell application "Pixelmator Pro"
	open vFichier
	repeat with E from 1 to 9
		tell front document --"Kool-Andy-Tribute_[empty].pxd"
			-- set image effect
			tell its group layer "Zero"
				tell image layer "Image"
					apply effects preset name vNom's item E
				end tell
			end tell
			-- set background color
			tell its group layer "Zero"
				set the fill color of the styles of image layer "Fond" to my fRGB16(vFond's item E)
			end tell
		end tell
		-- save as JPEG element for final File
		export the front document to file ((vFldrTEMP as text) & vNom's item E & ".png") as PNG
	end repeat
	close front document saving no
	make new document at end with properties {width:3072, height:3072} -- Make the Final File
	set vPlacePOS to {{0, 0}, {1024, 0}, {2048, 0}, {0, 1024}, {1024, 1024}, {2048, 1024}, {0, 2048}, {1024, 2048}, {2048, 2048}}
	repeat with E from 1 to 9 -- place JPEG previous created on final page
		tell the front document
			set vFilePath to ((vFldrTEMP as text) & vNom's item E & ".png")
			make new image layer with properties {file:vFilePath, preserve transparency:false, constrain proportions:true, position:vPlacePOS's item E, width:1024, height:1024}
		end tell
	end repeat
	-- Save Final File
	save front document in file ((path to desktop as text) & "Kool-Andy-Tribute.pxd")
	display dialog "The new file result is on the 'Desktop'" buttons {"OK"} default button "OK"
end tell

on fRGB16(pRGB8)
	return {(pRGB8's item 1) * 257, (pRGB8's item 2) * 257, (pRGB8's item 3) * 257}
end fRGB16


A revised my submission and here the new Kit.

1- New PXD (without “Effects”)
2- Revised script allowing to “include” Effects required to achieved the concept.
3- A folder containing 9 “.effect” Files

PXLmator_Conterst_v2.zip (2.0 MB)

Enjoy! (Hopefully…)