UI Browser not working on Ventura

Hi, I have recently upgraded to Ventura and have encountered an issue with the UI Browser on macOS 13.2.1. Despite having performed a clean installation, the trial window fails to display. I am curious as to whether there exists any means to reset the 30-day trial period. TIA

Yes, there is a way to reset the trial period. But I can’t remember it off the top of my head, so I won’t be able to post it here until I have time to look it up. Since UI Browser is no longer being sold, I am willing to post the solution publicly. In summary, you have to (1) delete your UI Browser preferences file (which is in the standard location for application preference files), (2) delete a secret file in a secret location (this is what I don’t remember off the top of my head), and (3) restart your Mac.

2 Likes

This is what i have found and removed so far.

Image

I have AppleScript scripts that will automatically"Reset UI Browser Preferences", “Unregister UI Browser eSellerate Key”, and “Unregister UI Browser Paddle key”. That last script also reinstates the 30-day trial period. I can ask Mark to post them on the website if anybody is interested.

2 Likes
-- Unregister UI Browser Paddle key
-- Version 1.0.0 Bill Cheeseman 2019-07-18

(*
This script unregisters UI Browser by deleting the "561201.padl", "561201.spadl" and "com.pfiddlesoft.uibrowser.ipak" files from the ~/Library/Application Support/UI Browser folder. This will reinstate UI Browser's 30-day free trial period.

If you run this script and then re-enter the same Paddle registration key in UI Browser a few times, the Paddle Activation dialog will refuse to reactivate the key because the limited number of activations will be used up. To avoid this problem, always choose UI Browser > Registration > Deactivate Key and deactivate the key immediately after running this script.
*)

use scripting additions

set registrationPath to (path to application support from user domain as string) & "UI Browser:"
set bundleID to "com.pfiddlesoft.uibrowser"

try
	set appName to name of application id bundleID
on error errMsg number errNum
	if errNum is -1728 then
		display alert appName & " is not installed." message "Application " & appName & " is not installed on this computer." --buttons {"OK"} default button "OK"
		return
	end if
end try

if application id bundleID is running then
	display alert appName & " is running." message "Registration information cannot be reset while the application is running. Quit " & appName & " and try again." --buttons {"OK"} default button "OK"
	return
end if

if not (exists file (registrationPath & "com.pfiddlesoft.uibrowser.ipak") of application "Finder") then
	display alert appName & " is not currently registered with a Paddle key" message "The " & appName & " User Library contains no Paddle registration information."
	return
end if

display alert "Unregister " & appName & "?" message appName & "'s Paddle registration information will be deleted" as critical buttons {"Unregister", "Cancel"} default button "Cancel"
if button returned of result is "Cancel" then return

-- Delete UI Browser registration information
try
	tell application "Finder"
		delete file (registrationPath & "561201.padl")
		delete file (registrationPath & "561201.spadl")
		delete file (registrationPath & "com.pfiddlesoft.uibrowser.ipak")
	end tell
	-- do shell script "defaults write " & bundleID & space & "\"First run\" -bool 'yes'"
	display alert appName & " was unregistered" message appName & " is no longer registered. Be sure to perform UI Browser's Deactivate command now to avoid exhausting the available activations."
on error errMsg number errNum
	display alert "Error " & errNum message errMsg
end try
4 Likes

I posted the script to this thread on Friday, March 10, at about 5:30 AM EST.

1 Like

Bill, Thank you for the script, unfortunately i’m getting an error.

System
macOS 13.2.1

Error Message

image

1 Like

I have installed UI Browser on another computer, but unfortunately, I am unable to locate the file “561201.spadl” in the application support. What am i missing here?

how many activations do you have on a single license for UI Browser 3? I manage to exhaust mine. I am trying to re-trace how many I used or if I wasted one when I had to rebuild my Mac mini.

updated: I realized it is 3…says right on the notification. Is there a point where activations (and deactivations) won’t anymore though?

Hey Bill, I guess you’ve really retired, even the domain name listed in your profile ;(

I get the same error. I guess we can just comment out the lines that delete the *.padl files…