Navigate between splits?

Script Debugger
#1

Is there a keystroke to switch panes of a split? (i.e., in top, go to bottom; in bottom, go to top)

#2

Sorry, there is nothing for this.

#3

Hey Mitchell,

That is an annoyance isn’t it.

System Events and GUI-Scripting to the rescue.

The script should be fairly robust in terms of working whether the Result, Resources, or Inspector Tabs are open or closed.

It’s a trifle slower than I’d expect, but it works.

-Chris

--------------------------------------------------------------------------------
# Auth: Christopher Stone
# dCre: 2015/10/03 03:28
# dMod: 2016/08/10 21:06
# Appl: Script Debugger
# Task: Return Focus to the Edit Pane of the front script window.
# Libs: None
# OSAX: None
# Tags: @Applescript, @Change, @Focus, @Edit, @Pane, @Split
--------------------------------------------------------------------------------

try
   
   tell application "System Events"
      tell (first application process whose bundle identifier is "com.latenightsw.ScriptDebugger6")
         if window 1's subrole is "AXStandardWindow" then
            tell (first window whose subrole is "AXStandardWindow")
               tell splitter group 1 of splitter group 1 of splitter group 1 of group 2
                  
                  if exists of scroll area 2 then
                     tell text area 1 of scroll area 2
                        if focused = false then
                           set focused to true
                           return
                        end if
                     end tell
                  end if
                  
                  tell text area 1 of scroll area 1
                     set focused to true
                  end tell
                  
               end tell
            end tell
         end if
      end tell
   end tell
   
on error e number n
   set e to e & return & return & "Num: " & n
   if n ≠ -128 then
      try
         tell application (path to frontmost application as text) to set ddButton to button returned of ¬
            (display dialog e with title "ERROR!" buttons {"Copy Error Message", "Cancel", "OK"} ¬
               default button "OK" giving up after 30)
         if ddButton = "Copy Error Message" then set the clipboard to e
      end try
   end if
end try

--------------------------------------------------------------------------------
#4

Aha! We found a legitimate missing feature!! I would like to put in a strong vote for adding this. Any other editor/IDE I’ve used that supports splits has this. Shouldn’t take much.

Though of course as Chris shows, you can’t stop us with missing features! :wink: Sit! Roll over!! Good system. :smile: