Meehow
March 16, 2020, 5:35pm
#1
Hello all.
I’m new to AppleScript and I am hoping it will reduce some Dynamometer data gathering men hours at my company.
And as such I would be happy to pay someone to write a script with comments and help start me off on this powerful tool by way of good example.
The Script would have to open multiple .txt files, one file at a time,
copy them into Numbers
filter data
get averages for Torque, Speed, Battery Voltage, Motor Power
Name the Row according to file name
go to next file until all files in the folder are processed.
Please direct message me if interested. Pay is negotiable.
Meehow
estockly
March 16, 2020, 7:22pm
#2
My approach would be to read all the files at once and save them into a list of lists. (You didn’t mention how the data was delimited, but that’s not an issue).
The filtering could be done on all at once, or a single file at a time.
Naming the row in Numbers is simply (I’m assuming you mean labeling the row using the first cell).
This wouldn’t take long. If no one offers to help, let me know.
You may want to compress and post a few sample files, and a an example of a completed numbers document.
Meehow
March 16, 2020, 8:06pm
#3
Thank you @estockly , yes I would go into more details and forward some sample data and how I would like it to be presented. I simply outlined the steps in how I performed them manually.
Meehow
March 17, 2020, 1:46am
#4
The data is in the form of a .txt file and it is Tab delimited.
estockly
March 17, 2020, 2:07am
#5
If no one has offered to do this for a price, just post the material and someone (like me) will just do it. (For a bigger, more complex job people might want to get paid.)
Meehow
March 17, 2020, 2:48am
#6
my apologies, I’m super new to this forum and I don’t even know if direct messaging is possible.
There is a .txt file that has the data and there is also a .bmp chart representation of the data… I put a series switch on the battery sensor, and I press it when I think is a good time to take a sample… So one of the filters (in Numbers) says show if “Battery Voltage > 18V”
Another filter discards any Row with “Speed = 0”, due to data acquisition glitches.
Then I take the 3-4 Columbus and get their averages and manually input them into a new spread sheet.
From a manual perspective it’s pretty simple, but there’s just a lot of this type of data and it’s worth paying someone to help me with the learning curve on this type of coding.
I also have another project that involves writing a script in Matlab to process .isf files from a Tektronix scope… but that is a matter for a different forum.
Here’s raw paste of one of the .txt files.
TIME SPEED MOTOR TORQUE MOTOR POWER - OUTPUT DC VOLTAGE N/A N/A N/A N/A N/A N/A N/A N/A N/A N/A N/A N/A N/A N/A N/A N/A
koenigyvan
April 20, 2020, 10:11am
#7
You may try:
set theSources to choose file of type {"txt"} with multiple selections allowed
set deci_loc to text item 2 of (0.5 as string)
tell application "Numbers"
set average_loc to localized string "AVERAGE" from table "TSCalculationEngine"
end tell
repeat with theSource in theSources
tell application "Finder" to set fileName to name of theSource
set theData to read theSource as «class utf8»
if theData does not contain deci_loc then
set theData to my remplace(theData, ".", deci_loc)
set targetFile to ((path to temporary items as string) & "localized.txt") as «class furl»
my writeto(targetFile, theData, «class utf8», false)
set trueSource to targetFile -- use the localized file
else
set trueSource to theSource -- use the original file
end if
tell application "Numbers"
set myDoc to open trueSource
tell myDoc to tell sheet 1 to tell table 1
add row below last row
set footer row count to 1 -- converts the added row into footer row
tell row -1
set value of cell 1 to fileName
repeat with c from 2 to 5
tell me to set colName to character id (64 + c)
set value of cell c to "=" & average_loc & "(" & colName & ")"
end repeat
end tell -- row -1
end tell -- myDoc…
save myDoc in (((path to documents folder as string) & fileName & ".numbers") as «class furl»)
end tell -- Numbers
end repeat
#=====
(*
replaces every occurences of d1 by d2 in the text t
*)
on remplace(t, d1, d2)
local oTIDs, l
set {oTIDs, AppleScript's text item delimiters} to {AppleScript's text item delimiters, d1}
set l to text items of t
set AppleScript's text item delimiters to d2
set t to l as text
set AppleScript's text item delimiters to oTIDs
return t
end remplace
#=====
(*
Handler borrowed to Regulus6633 - http://macscripter.net/viewtopic.php?id=36861
*)
on writeto(targetFile, theData, dataType, apendData)
-- targetFile is the path to the file you want to write
-- theData is the data you want in the file.
-- dataType is the data type of theData and it can be text, list, record etc.
-- apendData is true to append theData to the end of the current contents of the file or false to overwrite it
try
set targetFile to targetFile as «class furl»
set openFile to open for access targetFile with write permission
if not apendData then set eof openFile to 0
write theData to openFile starting at eof as dataType
close access openFile
return true
on error
try
close access file targetFile
end try
return false
end try
end writeto
#=====
1 Like
Meehow
April 20, 2020, 2:54pm
#8
WOW thank you @koenigyvan , that code is a good start and enough to get me past the first 10 hurdles which is a MAJOR help!
Where do I deposit funds?
I don’t ask for funds for such small script.